# author: Matteo Settenvini

// Manual: https://github.com/inkle/ink/blob/master/Documentation/WritingWithInk.md

VAR stat_assertiveness = 0
VAR stat_empathy = 0

-> disclaimer

=== disclaimer ===

This is a work of fiction. Names, characters, businesses, places, events, locales, and incidents are either the products of the author’s imagination or used in a fictitious manner. Any resemblance to actual persons, living or dead, or actual events is purely coincidental. # CLASS: disclaimer

+ [Understood] # CLEAR: -> intro

=== intro ===

= waking_up

The alarm clock unstoppably rings at {~six|seven|eight|nine} sharp, for it is Monday and you have to get up. Yes, it tolls for thee. It makes a ruckus like it were hell's bells. There's no escape, the only thing left: getting up for work.

Rise and shine!

- (opts)
    * [Get dressed] You {~slip out of your pyjamas|jump off your bed|carefully stretch your arms} and {~put on some clothes|wisely decide to keep your webcam off for the day|rummage in the wardrobe|pick up a t-shirt and some jeans from the floor}. You feel marginally better. -> opts
    * [Hit the bathroom] You {~wash your teeth|take a cold shower|relieve your bladder}. This makes you feel a tad better. -> opts
    * [Drag yourself to the kitchen] You {~stumble|drag yourself|walk gingerly} to the kitchen and {~turn on the coffee machine|pick some fresh milk and müsli|fry some eggs and beacon}. Your mood improves somewhat. -> opts
    * -> done
- (done) You feel ready to get on with the rest of your day.

-> logging_in

= logging_in

You sit down in front of your computer, {~coffee|tea|erva mate} firmly in hand. You boot it up, ready to tackle the stream of emails and messages that surely have accumulated during the last few days.

Okay, booted. You are ready.

* [Log in] -> first_troubles_ahead

== first_troubles_ahead

TODO: Example of conversation:

I don't want to hear it! # CLASS: message-sx

Don't you, now. # CLASS: message-dx

* [Be nice.] 
  ~ stat_empathy++ 
  -> ending

* [Be naughty.] 
  -> ending

=== ending ===

You have reached the end.

{ print_stat("{~empathy|understanding|awareness}", stat_empathy) }
{ print_stat("{~assertiveness|decisiveness|resoluteness}", stat_assertiveness) }

-> END

// ------------ HELPER functions ------------------

=== function print_stat(name, stat) ====

You {~have used|decided to employ|went to use} the power of {name} {print_num(stat)} time{stat != 1:s}.


=== function print_num(x) ===
{
    - x >= 1000:
        {print_num(x / 1000)} thousand { x mod 1000 > 0:{print_num(x mod 1000)}}
    - x >= 100:
        {print_num(x / 100)} hundred { x mod 100 > 0:and {print_num(x mod 100)}}
    - x == 0:
        zero
    - else:
        { x >= 20:
            { x / 10:
                - 2: twenty
                - 3: thirty
                - 4: forty
                - 5: fifty
                - 6: sixty
                - 7: seventy
                - 8: eighty
                - 9: ninety
            }
            { x mod 10 > 0:<>-<>}
        }
        { x < 10 || x > 20:
            { x mod 10:
                - 1: one
                - 2: two
                - 3: three
                - 4: four
                - 5: five
                - 6: six
                - 7: seven
                - 8: eight
                - 9: nine
            }
        - else:
            { x:
                - 10: ten
                - 11: eleven
                - 12: twelve
                - 13: thirteen
                - 14: fourteen
                - 15: fifteen
                - 16: sixteen
                - 17: seventeen
                - 18: eighteen
                - 19: nineteen
            }
        }
}