dnl @synopsis AC_PYTHON_DEVEL
dnl
dnl Checks for Python and tries to get the include path to 'Python.h'.
dnl It provides the $(PYTHON_CPPFLAGS) and $(PYTHON_LDFLAGS) output
dnl variables.
dnl Also exports $(PYTHON_EXTRA_LIBS) and $(PYTHON_EXTRA_LDFLAGS)
dnl for embedding Python in your code.
dnl If the user wants to employ a particular version of Python, she can
dnl now pass to configure the PYTHON_VERSION environment variable.
dnl Should work for all versions of Python >= 2.1.0. You can disable the
dnl check for the python version by setting the PYTHON_NOVERSIONCHECK
dnl environment variable.
dnl
dnl @category InstalledPackages
dnl @author Sebastian Huber <sebastian-huber@web.de>
dnl @author Alan W. Irwin <irwin@beluga.phys.uvic.ca>
dnl @author Rafael Laboissiere <laboissiere@psy.mpg.de>
dnl @author Andrew Collier <colliera@nu.ac.za>
dnl @author Matteo Settenvini <matteo@member.fsf.org>
dnl @version 2006-01-29
dnl @license GPLWithACException

AC_DEFUN([AC_PYTHON_DEVEL],[
	#
	# Allow use of a custom python version
	#
	AC_ARG_VAR([PYTHON_VERSION],[The installed Python
		version to link against, for example '2.3'])
	AC_PATH_PROG([PYTHON],[python[$PYTHON_VERSION]])

	if test -z "$PYTHON"; then
	   AC_MSG_ERROR([Cannot find python$PYTHON_VERSION in your system path])
	fi

	#
	# Check for a version of Python >= 2.1.0
	#
	AC_MSG_CHECKING([for a version of Python >= 2.1.0])
	ac_supports_python_ver=`$PYTHON -c "import sys, string; \
		print string.split(sys.version)[[0]] >= '2.5.0'"`
	if test "$ac_supports_python_ver" != "True"; then
		if test -z "$PYTHON_NOVERSIONCHECK"; then
			AC_MSG_RESULT([no])
			AC_MSG_FAILURE([
This version of the AC@&t@_PYTHON_DEVEL macro
doesn't work properly with versions of Python before
2.1.0. You may need to re-run configure, setting the
variables PYTHON_CPPFLAGS, PYTHON_LDFLAGS, PYTHON_SITE_PKG,
PYTHON_EXTRA_LIBS and PYTHON_EXTRA_LDFLAGS by hand.
Moreover, to disable this check, set PYTHON_NOVERSIONCHECK
to something else than an empty string.
])dnl
		else
			AC_MSG_RESULT([skip at user request])
		fi
	else 
		AC_MSG_RESULT([yes])
	fi
	
	#
	# Check for Python include path
	#
	AC_MSG_CHECKING([for Python include path])
		python_path=`$PYTHON -c "import distutils.sysconfig; \
               	print distutils.sysconfig.get_python_inc();"`
		AC_MSG_RESULT([$python_path])
	if test -z "${python_path}"; then
		AC_MSG_WARN([cannot get include path. Please set it by hand.])
	else
		python_path="-I$python_path"
	fi
	AC_SUBST([PYTHON_CPPFLAGS],[$python_path])

	#
	# Check for Python library path
	#
	AC_MSG_CHECKING([for Python library path])
		python_path=`$PYTHON -c "from distutils.sysconfig import *; \
		from string import join; \
		print '-L' + get_python_lib(0,1), \
		      '-lpython' + join(get_config_vars('VERSION'));"`
		AC_MSG_RESULT([$python_path])
	AC_SUBST([PYTHON_LDFLAGS],[-I$python_path])

	#
	# Check for site packages
	#
	AC_MSG_CHECKING([for Python site-packages path])
		python_site=`$PYTHON -c "import distutils.sysconfig; \
               	print distutils.sysconfig.get_python_lib(0,0);"`
		AC_MSG_RESULT([$python_site])
	AC_SUBST([PYTHON_SITE_PKG],[$python_site])

	#
	# libraries which must be linked in when embedding
	#
	AC_MSG_CHECKING(python extra libraries)
	PYTHON_EXTRA_LIBS=`$PYTHON -c "import distutils.sysconfig; \
                conf = distutils.sysconfig.get_config_var; \
                print conf('LOCALMODLIBS'), conf('LIBS')"`
	AC_MSG_RESULT([$PYTHON_EXTRA_LIBS])
	AC_SUBST(PYTHON_EXTRA_LIBS)

	#
	# linking flags needed when embedding
	#
	AC_MSG_CHECKING(python extra linking flags)
	PYTHON_EXTRA_LDFLAGS=`$PYTHON -c "import distutils.sysconfig; \
		conf = distutils.sysconfig.get_config_var; \
		print conf('LINKFORSHARED')"`
	AC_MSG_RESULT([$PYTHON_EXTRA_LDFLAGS])
	AC_SUBST(PYTHON_EXTRA_LDFLAGS)
])