# configure.ac - Copyright 2005, University
#                of Padova, dept. of Pure and Applied
#                Mathematics
#
# This file is part of SGPEMv2.
#
# This is free software; you can redistribute it and/or modify
# it under the terms of the GNU General Public License as published by
# the Free Software Foundation; either version 2 of the License, or
# (at your option) any later version.
#
# SGPEMv2 is distributed in the hope that it will be useful,
# but WITHOUT ANY WARRANTY; without even the implied warranty of
# MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
# GNU General Public License for more details.
#
# You should have received a copy of the GNU General Public License
# along with SGPEMv2; if not, write to the Free Software
# Foundation, Inc., 51 Franklin St, Fifth Floor, Boston, MA 02110-1301 USA

dnl ----------------- CONFIGURE ---------------------

AC_INIT([sgpemv2-xmlsave],[0.9b],[matteo@member.fsf.org])

if test -f "`pwd`/configure.ac"; then
        AC_MSG_FAILURE([
  ** This seems to be the pkg root directory.
	** Compiling here your sources is considered
	** as unpolite as exploring your nose with 
	** your pinky whilst attending a wedding party.
  ** Please create a new dir as described in
  ** the README file, and then run configure
  ** into it. If you think you've got it right, 
	** please inform the mantainer of this error!
	** He'll thoroughfully bash his head on the wall.], 
	-1 )
fi

AC_GNU_SOURCE
AC_CONFIG_AUX_DIR(config)

AC_CANONICAL_TARGET

dnl starting automake
AM_INIT_AUTOMAKE([dejagnu dist-bzip2 subdir-objects])

dnl gettext & libtool
AC_PROG_LIBTOOL
AM_GNU_GETTEXT([external])
AM_GNU_GETTEXT_VERSION([0.14.1])

dnl PYTHON_VERSION is declared precious by AC_PYTHON_DEVEL,
dnl so don't use it here
LIBXML2_VERSION=2.6.10
GTKMM_VERSION=2.8.0
SGPEMV2_VERSION=0.3

dnl c++ compiler and flags
AC_PROG_CXX
AC_CHECK_CXXFLAG([CXXFLAGS], [Wall])
AC_CHECK_CXXFLAG([CXXFLAGS], [pedantic])
AC_CHECK_CXXFLAG([CXXFLAGS], [Wextra])
AC_CHECK_CXXFLAG([CXXFLAGS], [Wno-long-long])
AC_CHECK_LDFLAG([LDFLAGS], [--as-needed])

dnl see if we've to enable debug flags
AC_ARG_ENABLE([debug], 
    AS_HELP_STRING([--enable-debug],
      [turn on debug compiler flags. Disabled by default]), 
    [enable_debug="$enableval"], [enable_debug="no"])

if test "$enable_debug" = "yes"; then
  AC_CHECK_CXXFLAG([CXXFLAGS], [O0])
  AC_CHECK_CXXFLAG([CXXFLAGS], [g3])
else
  AC_CHECK_CXXFLAG([CXXFLAGS], [DNDEBUG])
fi

AC_PROG_INSTALL

dnl make
AC_PROG_MAKE_SET

dnl add pkg-config search path for sgpemv2-uninstalled.pc 
dnl if we're building in a subdir of that pkg it will be 
dnl in $build_dir/config
_old_pkg_path=$[]PKG@&t@_CONFIG_PATH
export PKG_@&t@CONFIG_PATH="./config:$PKG_CONFIG_PATH"

dnl check for sgpemv2!
AC_PROG_SGPEMV2([$SGPEMV2_VERSION])

dnl revert from old var
dnl FIXME: probably you can safely remove this block:
if test "x$_old_pkg_path" = "x"; then
	unset -v PKG@&t@_CONFIG_PATH
else
	export PKG@&t@_CONFIG_PATH="$_old_pkg_path"
fi

dnl check for glib & cairo
PKG_CHECK_MODULES([GTHREAD], 
		[gthread-2.0 >= $GTKMM_VERSION],
		:, AC_MSG_ERROR([$GTHREAD_PKG_ERRORS]))
PKG_CHECK_MODULES([GLIBMM], 
		[glibmm-2.4 >= $GTKMM_VERSION],
		:, AC_MSG_ERROR([$GLIBMM_PKG_ERRORS]))
PKG_CHECK_MODULES([LIBXML2],
		[libxml-2.0 >= $LIBXML2_VERSION],
		:, AC_MSG_ERROR([$LIBXML2_PKG_ERRORS]))


dnl use DSO visibility tags for systems that supports it correctly
SGPEMV2_VISIBILITY_SUPPORT

dnl see if we've to compile tests
AC_MSG_CHECKING([whether tests have to be built])
AC_ARG_ENABLE([tests],
   AS_HELP_STRING([--disable-tests], 
                  [don't compile the tests provided with sgpemv2]),
   [compile_tests="$enableval"],
   [compile_tests="yes"])
AC_MSG_RESULT([$compile_tests])
AM_CONDITIONAL([COND_TESTS], [test "$compile_tests" = "yes"])

dnl output files
AC_CONFIG_HEADERS([config.h:config.h.in])

AC_CONFIG_FILES([ 
Makefile
po/Makefile.in
])
AC_OUTPUT
